iAlligator関数とは？なぜトレンド判定に使われるのか

アリゲーター（Alligator）はビル・ウィリアムズが考案したインジケーターです。移動平均線を時間軸でずらした3本のラインで構成されており、ラインが開くとトレンド発生、収束するとレンジ相場という状態を示します。

MQL4では iAlligator() 関数でこの3本のライン値をリアルタイムに取得できるため、「トレンドが発生しているときだけエントリーする」というフィルターロジックをEAに組み込めます。

iAlligator() の構文と引数

double iAlligator(
    string symbol,          // 通貨ペア（NULLで現在のチャート）
    int    timeframe,       // 時間足（0で現在の時間足）
    int    jaw_period,      // 顎の期間（デフォルト13）
    int    jaw_shift,       // 顎のシフト（デフォルト8）
    int    teeth_period,    // 歯の期間（デフォルト8）
    int    teeth_shift,     // 歯のシフト（デフォルト5）
    int    lips_period,     // 唇の期間（デフォルト5）
    int    lips_shift,      // 唇のシフト（デフォルト3）
    int    ma_method,       // 移動平均の種類（MODE_SMMA推奨）
    int    applied_price,   // 適用価格（PRICE_MEDIAN推奨）
    int    mode,            // 取得するライン
    int    shift            // 何本前のバーか（0=現在）
);

mode の値

基本的な使い方：3本のライン値を取得する

iAlligator関数でアリゲーターの各ラインを取得する最もシンプルなコードです。

// アリゲーターのデフォルト設定で3本のライン値を取得
double jaw   = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORJAW,   1);
double teeth = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORTEETH, 1);
double lips  = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORLIPS,  1);

Print("顎(Jaw): ",   jaw);
Print("歯(Teeth): ", teeth);
Print("唇(Lips): ",  lips);

実践例1：アリゲーターでトレンドフィルターを作る

アリゲーターの3本のラインの並び順でトレンドを判定します。唇 > 歯 > 顎なら上昇トレンド、顎 > 歯 > 唇なら下降トレンドと判断できます。

// トレンド判定関数
// 戻り値: 1=上昇トレンド / -1=下降トレンド / 0=レンジ（睡眠中）
int GetAlligatorTrend()
{
    double jaw   = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORJAW,   1);
    double teeth = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORTEETH, 1);
    double lips  = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORLIPS,  1);

    // 唇 > 歯 > 顎 → 上昇トレンド
    if(lips > teeth && teeth > jaw)
        return 1;

    // 顎 > 歯 > 唇 → 下降トレンド
    if(jaw > teeth && teeth > lips)
        return -1;

    // それ以外 → レンジ（アリゲーターが眠っている状態）
    return 0;
}

void OnTick()
{
    int trend = GetAlligatorTrend();
    if(trend == 1)
        Comment("アリゲーター: 上昇トレンド");
    else if(trend == -1)
        Comment("アリゲーター: 下降トレンド");
    else
        Comment("アリゲーター: レンジ（様子見）");
}

実践例2：アリゲーターをフィルターにしたEA

iAlligator関数のトレンド判定と iMA（移動平均）のゴールデンクロスを組み合わせた実践的なEAです。アリゲーターがトレンドを示しているときだけエントリーするため、ダマシを減らせます。

extern int    MagicNumber = 20001;
extern double Lots        = 0.1;
extern int    FastMA      = 5;
extern int    SlowMA      = 20;

void OnTick()
{
    // ラインが3本とも開いているか（絶対値で判定）
    double jaw   = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORJAW,   1);
    double teeth = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORTEETH, 1);
    double lips  = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORLIPS,  1);

    bool upTrend   = (lips > teeth && teeth > jaw);
    bool downTrend = (jaw  > teeth && teeth > lips);

    // MAクロス判定
    double fastMA_cur  = iMA(NULL, 0, FastMA, 0, MODE_EMA, PRICE_CLOSE, 1);
    double fastMA_prev = iMA(NULL, 0, FastMA, 0, MODE_EMA, PRICE_CLOSE, 2);
    double slowMA_cur  = iMA(NULL, 0, SlowMA, 0, MODE_EMA, PRICE_CLOSE, 1);
    double slowMA_prev = iMA(NULL, 0, SlowMA, 0, MODE_EMA, PRICE_CLOSE, 2);

    bool goldenCross = (fastMA_prev < slowMA_prev && fastMA_cur > slowMA_cur);
    bool deadCross   = (fastMA_prev > slowMA_prev && fastMA_cur < slowMA_cur);

    if(OrdersTotal() > 0) return;

    // アリゲーターが上昇トレンド ＋ ゴールデンクロス → 買い
    if(upTrend && goldenCross)
    {
        OrderSend(Symbol(), OP_BUY, Lots, Ask, 20, 0, 0,
                  "Alligator+MA", MagicNumber, 0, clrBlue);
    }

    // アリゲーターが下降トレンド ＋ デッドクロス → 売り
    if(downTrend && deadCross)
    {
        OrderSend(Symbol(), OP_SELL, Lots, Bid, 20, 0, 0,
                  "Alligator+MA", MagicNumber, 0, clrRed);
    }
}

iAlligator使用時の注意点

• シフトに注意：アリゲーターは各ラインが未来方向にシフトされるため、チャート上の表示位置とバーインデックスがずれます。shift=1（1本前）を使って確定済みのバーを参照するのが基本です。
• レンジ相場では使わない：3本のラインが絡み合っている（アリゲーターが眠っている）状態でのエントリーはダマシが増えます。必ず上記のトレンド判定と組み合わせてください。
• applied_price はPRICE_MEDIAN：ビル・ウィリアムズのオリジナル設定は中値（(High+Low)/2）です。PRICE_CLOSEで計算するとチャートの表示と一致しないことがあります。

まとめ

iAlligator関数は、アリゲーターインジケーターの顎・歯・唇の3本のライン値をMQL4から直接取得できる関数です。ラインの並び順を見るだけでトレンドの有無・方向を判定できるため、EA開発のフィルターとして非常に使いやすいのが特徴です。

レンジ相場（アリゲーターが眠っている状態）ではエントリーを避け、トレンドが明確に出たときだけ他のシグナルと組み合わせるのがiAlligator活用のポイントです。

投稿 【MQL4関数】iAlligator関数の使い方！アリゲーターでトレンド判定EAを作ろう は 自動売買を作ろう！ に最初に表示されました。

MQL4では iEnvelopes() 関数を使ってエンベロープの値を取得できます。

iEnvelopes() の構文

double iEnvelopes(
    string  symbol,       // 通貨ペア（NULLで現在のチャート）
    int     timeframe,    // 時間足（0で現在の時間足）
    int     ma_period,    // 移動平均の期間
    int     ma_method,    // 移動平均の種類
    int     ma_shift,     // 移動平均のシフト
    int     applied_price,// 適用価格
    double  deviation,    // 偏差（%）
    int     mode,         // バンドの種類（上・下）
    int     shift         // 何本前のバーか（0=現在）
);

引数の詳細

mode の値

基本的な使い方

// 20期間SMA、偏差0.2%のエンベロープを取得する
double upperBand = iEnvelopes(NULL, 0, 20, MODE_SMA, 0, PRICE_CLOSE, 0.2, MODE_UPPER, 0);
double lowerBand = iEnvelopes(NULL, 0, 20, MODE_SMA, 0, PRICE_CLOSE, 0.2, MODE_LOWER, 0);

Print("上バンド: ", upperBand);
Print("下バンド: ", lowerBand);

実践例1：エンベロープのブレイクアウトでエントリー

価格が上バンドを上抜けたら買い、下バンドを下抜けたら売りのシグナルとして使う例です。

extern int    MagicNumber = 11001;
extern double Lots        = 0.1;
extern int    MA_Period   = 20;
extern double Deviation   = 0.2;  // バンド幅（%）

//+------------------------------------------------------------------+
//| エンベロープ ブレイクアウトEA                                       |
//+------------------------------------------------------------------+
void OnTick()
{
    // すでにポジションがある場合はスキップ
    if(OrdersTotal() > 0) return;

    double upperBand = iEnvelopes(NULL, 0, MA_Period, MODE_SMA, 0, PRICE_CLOSE, Deviation, MODE_UPPER, 1);
    double lowerBand = iEnvelopes(NULL, 0, MA_Period, MODE_SMA, 0, PRICE_CLOSE, Deviation, MODE_LOWER, 1);
    double prevClose = iClose(NULL, 0, 2);  // 2本前の終値
    double lastClose = iClose(NULL, 0, 1);  // 1本前の終値

    // 上バンドを上抜け → 買いエントリー
    if(prevClose < upperBand && lastClose > upperBand)
    {
        OrderSend(Symbol(), OP_BUY, Lots, Ask, 20, 0, 0,
                  "Envelope Breakout", MagicNumber, 0, clrBlue);
    }

    // 下バンドを下抜け → 売りエントリー
    if(prevClose > lowerBand && lastClose < lowerBand)
    {
        OrderSend(Symbol(), OP_SELL, Lots, Bid, 20, 0, 0,
                  "Envelope Breakout", MagicNumber, 0, clrRed);
    }
}

実践例2：エンベロープをトレンドフィルターとして使う

価格が上バンドより上にある＝上昇トレンドと判断し、他のシグナルと組み合わせるフィルターとして活用する例です。

// トレンドフィルター関数
// 戻り値: 1=上昇トレンド / -1=下降トレンド / 0=レンジ
int GetTrend()
{
    double upperBand = iEnvelopes(NULL, 0, 20, MODE_SMA, 0, PRICE_CLOSE, 0.2, MODE_UPPER, 1);
    double lowerBand = iEnvelopes(NULL, 0, 20, MODE_SMA, 0, PRICE_CLOSE, 0.2, MODE_LOWER, 1);
    double lastClose = iClose(NULL, 0, 1);

    if(lastClose > upperBand) return  1;  // 上昇トレンド
    if(lastClose < lowerBand) return -1;  // 下降トレンド
    return 0;                             // レンジ（バンド内）
}

void OnTick()
{
    int trend = GetTrend();

    if(trend == 1)
        Comment("トレンド: 上昇（買いシグナルのみ有効）");
    else if(trend == -1)
        Comment("トレンド: 下降（売りシグナルのみ有効）");
    else
        Comment("トレンド: レンジ（様子見）");
}

実践例3：反転狙い（逆張り）

価格がバンドに触れたら反転を狙う逆張り戦略です。

extern int    MagicNumber = 11002;
extern double Lots        = 0.1;
extern int    MA_Period   = 30;
extern double Deviation   = 0.3;

void OnTick()
{
    if(OrdersTotal() > 0) return;

    double upperBand = iEnvelopes(NULL, 0, MA_Period, MODE_EMA, 0, PRICE_CLOSE, Deviation, MODE_UPPER, 1);
    double lowerBand = iEnvelopes(NULL, 0, MA_Period, MODE_EMA, 0, PRICE_CLOSE, Deviation, MODE_LOWER, 1);
    double high1     = iHigh(NULL, 0, 1);
    double low1      = iLow(NULL, 0, 1);

    // 上バンドに高値が触れた → 売り（反転狙い）
    if(high1 >= upperBand)
    {
        OrderSend(Symbol(), OP_SELL, Lots, Bid, 20, 0, 0,
                  "Envelope Mean Reversion", MagicNumber, 0, clrRed);
    }

    // 下バンドに安値が触れた → 買い（反転狙い）
    if(low1 <= lowerBand)
    {
        OrderSend(Symbol(), OP_BUY, Lots, Ask, 20, 0, 0,
                  "Envelope Mean Reversion", MagicNumber, 0, clrBlue);
    }
}

偏差（deviation）の目安

偏差が小さすぎるとノイズが多くなり、大きすぎるとシグナルが少なくなります。バックテストで最適な値を見つけましょう。

まとめ

• iEnvelopes() は移動平均の上下にバンドを描くインジケーター関数
• MODE_UPPER で上バンド、MODE_LOWER で下バンドの値を取得
• ブレイクアウト（トレンドフォロー）と反転狙い（逆張り）の両方に応用できる
• deviation パラメーターはバックテストで通貨ペアに合わせて調整する

投稿 【MQL4関数】iEnvelopes関数の使い方！エンベロープでトレンドフィルターEAを作ろう は 自動売買を作ろう！ に最初に表示されました。

朝日奈りさ

関数とは？

「プログラムは、何度も同じことを書かないといけない」

と思っている方、ぜひ関数を使ってみてください。

関数とは、何度も繰り返すプログラムを、まとめた状態のものです。

事前に、まとまりを作っておくことで、同じプログラムを何度も書く必要がなくなります。

【MQLプログラミング基礎】変数とは？使い方を詳しく解説！プログラム例あり

目次 変数とは？変数の使い方変数に保存されているデータの変更方法MQLプログラミングでの変数の使い方MQLプログラム例（MT4で動作可能）まとめ 変数とは？ 変数は、数字や文字などの、データを保存するための入れ物です。

mql-programing.com

たとえば、以下のようなプログラムのまとまりを関数と呼びます。

足し算をする関数です。

//MyFunctionという関数を作成します。
int MyFunction(int number)
  {

　　//numberという変数を読み込んで、suujiと足し算します。
   int suuji = 100;
   suuji = suuji + number;

　　//足し算の結果を返却します。
   return  suuji
  }

上記の例では、MyFunctionという関数を作成しました。

ちなみに、「MyFunction」じゃなくても、関数の名前はなんでもOKです。

「朝日奈りさSpecial」とかでOKです。（ダサい）

さて、ここからは上記の例を参考にしながら、関数の使い方について詳しく見ていきましょう。

関数のプログラム例

関数は、プログラム全体で見ると以下のように書きます。

//+------------------------------------------------------------------+
//|                                           SampleMQL_function.mq4 |
//|                                    Copyright 2021, 朝日奈りさFXchannel |
//|                                      https://mql-programing.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright 2021, 朝日奈りさFXchannel"
#property link      "https://mql-programing.com/"
#property version   "1.00"
#property strict
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   int suuji = MyFunction(10);
   Comment("\n","OnInit()という関数を実行します。",
   "suujiの結果は",suuji,"です。");

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   Comment("\n","OnDeinit()という関数を実行します。");
   

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   int suuji = MyFunction(20);
   Comment("\n","OnTick()という関数を実行します。",
   "suujiの結果は",suuji,"です。");

  }
//+------------------------------------------------------------------+

//MyFunctionという関数を作成します。
int MyFunction(int number)
  {

   //numberという変数を読み込んで、suujiと足し算します。
   int suuji = 100;
   suuji = suuji + number;

   //足し算の結果を返却します。
   return  suuji;
  }
//+------------------------------------------------------------------+

かなり分かりにくいと思いますが、一番下に関数を書いています。46~56行目です。

このようにOnInit,OnDeinit,OnTickとは、別の関数として、新しい関数を作ることができます。

OnInit,OnDeinit,OnTickについては以下の記事を参考にしてください。

【MQLプログラミング】自動売買（EA）の実行タイミングとは？MQLプログラム例あり

目次 自動売買プログラム（EA）の構造パターンとは大域・大域変数初期化関数（OnInit）プログラム例終了関数（OnDeinit）プログラム例メイン関数（OnTick）プログラム例まとめ 自動売買プログラム（EA）の構造

mql-programing.com

関数の基本的な使い方

上記のプログラムの16行目を見てください。以下のプログラムが書かれています。

int suuji = MyFunction(10);

MyFunctionを使っています。

細かく見ていくと、「suuji」というint型の変数を宣言しています。

その「suuji」にMyFunctionの計算結果を代入しているといったプログラムです。

関数はこのように使うことが多いので、このパターンを覚えておくと良いでしょう。

「あれ？MyFunction(int number)じゃないの？」と疑問に思った方は、プログラミングのセンスがあります。

なぜMyFunction(int number)ではなく、MyFunction(10)と書いているのかを、関数の構造を見ながら解説します。

関数の構造と書き方

関数の構造のポイントは以下の３点です。

• 引数
• 関数の内容
• 戻り値（返り値）

それぞれ見ていきましょう。

引数とメリット

引数とは、関数の内容で使用する値を、外部から持ってくるために存在します。

どういうことかというと、関数の中で変数を宣言しなくて良くなります。

メリットは、その関数を使って同じ計算をしたいとき、値を変えてもう一度計算させることができることです。

例えば、100+10を計算させたい時、「100+10」とそのまま書いてしまうと、結果は110にしかなりません。

しかし関数を使うことで、100+10の「10」の部分を「20」に変えて、「100+20」も計算させることができます。

つまり同じMyFunctionという関数を使って、「100+10」も「100+20」も計算できるのです。

引数の書き方

引数は、関数名の右横に宣言します。

上記の例を抜粋すると、以下の部分です。47行目です。

int MyFunction(int number)

「MyFunction」という関数名の右横に(int number)を書いています。

このnumberを引数と言います。

ちなみにint numberという書き方は、変数の書き方と同じなので、わかりやすいと思います。

引数は、関数の内容で使用される変数です。別の値を代入することもできます。

関数の内容

関数の内容は、計算させるルールを書きます。

上記の例だと、「100+引数」というルールを書いています。

何度も計算させたいことを書くと良いでしょう。

戻り値（返り値）

最後に戻り値です。返り値とも呼ばれます。

戻り値は、関数の計算結果を出力する時に使います。

これによって、関数で計算させるだけでなく、計算結果を引き継ぐことができます。

少しずつ見ていきましょう。

まずは書き方です。

戻り値の書き方は以下のようなパターンが多いです。

//関数を作成
int MyFunction(int number)
  {

   //関数の内容を書く

   //戻り値を出力
   return  suuji;
  }

ポイントは2つあります。

• 戻り値の型の宣言
• 戻り値の値を出力

それぞれ解説します。

戻り値の型の宣言

まず2行目の「int MyFunction(int number)」ですが、一番左に「int」が宣言されています。

これはMyFunctionという関数が計算した結果、int型の変数を出力することを表しています。

つまり、戻り値の型は「int型」になるのです。

ちなみに変数の型であれば、なんでも設定することができます。

変数の一覧は以下が参考になります。

【MQLリファレンス】データ型一覧　プログラム例あり

目次 データ型とは整数型(char, short, int, long, uchar, ushort, uint, ulong)使用例注意点とサンプルプログラム論理型(bool)使用例注意点とサンプルプログラムリテラル型

mql-programing.com

戻り値の値を出力

上記のプログラムの8行目をご覧ください。

suujiという変数を「return」しています。

return  suuji;

returnとは、変数や値を戻す（返す or 出力する）ために使うものです。

ほとんどの場合、プログラムの最後に書かれています。

このように書くことで、MyFunction関数は、int型のsuujiを戻すことができます。

「戻す」とは？

先ほどから何度も「戻す」という言葉を使っていますが、プログラミング界では一般的な言葉です。

関数を使うときに、「処理が戻ってくる」という意味から使われています。

どういうことかというと、関数を使うと、処理が関数に飛びます。

関数を使う時、以下のように使います。

int suuji = MyFunction(10);

MyFunctionに「10」を入力し、計算した結果をsuujiに代入します。

「MyFunctionに「10」を入力する」段階で、処理が一時的にMyFunctionに飛びます。

そしてMyFunctionの処理が終わった後（suujiが出力された後）、処理が戻ってきます。

この辺りは言葉で解説するのは難しいので、プログラム例を載せておきます。

この2つのプログラムの違いは、関数を使っているか使っていないかですが、全く同じ処理をします。

ぜひ見比べてみてください。

16~17行目あたりが違っています。

関数を使っていない場合

//+------------------------------------------------------------------+
//|                                           SampleMQL_function.mq4 |
//|                                    Copyright 2021, 朝日奈りさFXchannel |
//|                                      https://mql-programing.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright 2021, 朝日奈りさFXchannel"
#property link      "https://mql-programing.com/"
#property version   "1.00"
#property strict
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   int suuji = 100;
   suuji = suuji + 10;

   Comment("\n","OnInit()という関数を実行します。",
   "suujiの結果は",suuji,"です。");

//---
   return(INIT_SUCCEEDED);
  }

関数を使った場合

//+------------------------------------------------------------------+
//|                                           SampleMQL_function.mq4 |
//|                                    Copyright 2021, 朝日奈りさFXchannel |
//|                                      https://mql-programing.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright 2021, 朝日奈りさFXchannel"
#property link      "https://mql-programing.com/"
#property version   "1.00"
#property strict
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   int suuji = MyFunction(10);

   Comment("\n","OnInit()という関数を実行します。",
   "suujiの結果は",suuji,"です。");

//---
   return(INIT_SUCCEEDED);
  }

//+------------------------------------------------------------------+

//MyFunctionという関数を作成します。
int MyFunction(int number)
  {

   //numberという変数を読み込んで、suujiと足し算します。
   int suuji = 100;
   suuji = suuji + number;

   //足し算の結果を返却します。
   return  suuji;
  }
//+------------------------------------------------------------------+

まとめ

関数は計算のルールをまとめたプログラムです。

今回は足し算のルールを作ってみました。

関数には3つのポイントがあり、これをマスターすれば関数を使いこなすことができるでしょう。

• 引数
• 関数の内容
• 戻り値（返り値）

関数は正直難しいです。

初心者のかたは、関数を使うことは意識せず、まずはプログラムを作ってみましょう。

【MQL4プログラミング】自動売買の作り方！FXで使えるテンプレートあり

目次 はじめにFX自動売買とはFX自動売買を作るための準備FX自動売買の作り方口座凍結の対策をするプログラムテンプレートを作る決済ロジックをプログラミングするプログラムテンプレートを作るエントリーロジックをプログラミング

mql-programing.com

MQL4サンプルプログラム

朝日奈りさ作成したMQL4サンプルプログラムの一覧です。当サイトは、MQL4のサンプルプログラムを公開しています。プログラムの内容を見たり、変更したりできます。　当サイトはMQLプログラミングを学習するサイトです。ご利用の際には、プライバシ

mql-programing.com

投稿 【MQLプログラミング基礎】関数は難しい？関数の使い方を理解しよう！プログラム例あり は 自動売買を作ろう！ に最初に表示されました。